...
SCL-3025 Improved rendering of Labels on connectors in the Crainiate diagramming control
Description:
We have improved the rendering of connectors in the Crainiate diagramming Control. The control is used to implement the design surface of the Business Entity Designer. As a result of this change, labels on the child table of a Data-Relation (e.g. 1 or N and the relation field names) are no longer rendered up-side-down in some situations.
SCL-3029 Crainiate Shape Image no longer locking until end of AVM session
Description:
We have resolved an issue in the Crainiate diagramming control that caused images used to render shapes remaining locked until the application (e.g. Business Entity Designer) has been exited.
SCL-3030 Enabled wild card search in the Open Repository Object Dialog
Description:
The Open Repository Object Dialog now supports using the asterisk character to perform a wild card search in the object name field.
SCL-3031 Implemented improvements to the Folder/Package Browser Dialog
Description:
We have made the following improvements to the folder browser dialog used for instance in the Business Entity Designer to browse for a package or folders.
When used to browse for a Package we now:
- disallow creating new "folders" with a period or spaces in the name
- when returning existing folders, disallow those with period or spaces in the name
SCL-3034 Resolved performance issues while drawing the design surface in the Business Entity Designer
Description:
We have resolved an issue causing a rather disturbing delay after every user interaction with the design canvas shapes in the Business Entity Designer. The diagram works significantly more fluent now.
New Feature
SCL-3011 Workflow status diagram
Description:
Applications can embed a diagram displaying the current workflow status of any given workflow enabled record. The diagram renders the workflow diagram as present in the workflow maintenance as well and marks the current status with a red border.
For this purpose the WorkflowDiagramControl needs to be added to an application screen. To render a workflow on the diagram, the following code is required in a suitable event handler. This example here renders the workflow diagram in an Infragistics UltraPopupControlContainer and is activated by clicking on a Link Label control:
| Code Block | ||
|---|---|---|
| ||
/**
* Purpose: Event handler for the LinkClicked event of the linkLabel1
* Notes:
* @param sender The reference to the control that raised the event
* @param e The LinkLabelLinkClickedEventArgs with the data for this event
*/
METHOD PRIVATE VOID linkLabel1_LinkClicked (sender AS System.Object,
e AS System.Windows.Forms.LinkLabelLinkClickedEventArgs):
DEFINE VARIABLE oRenderer AS WorkflowProcessInstanceDiagramRenderer NO-UNDO .
DEFINE VARIABLE oPoint AS System.Drawing.Point NO-UNDO .
oPoint = THIS-OBJECT:PointToScreen (ultraComboEditor1:Location) .
oPoint:Offset (ultraComboEditor1:Width * -1 + ultraComboEditor1:Width, ultraComboEditor1:Height) .
ultraPopupControlContainer1:Show (ultraComboEditor1,
oPoint) .
oRenderer = NEW WorkflowProcessInstanceDiagramRenderer (THIS-OBJECT:workflowDiagramControl1) .
oRenderer:RenderWorkflowDiagram (SmartComponentsDemoServices:OERA:Sports2000:OrderBusinessEntity,
CAST (THIS-OBJECT:SmartDataSource, SmartDatasetAdapter):QueryHandle:GET-BUFFER-HANDLE("eOrder":U),
"OrderApproval":U) .
{Consultingwerk/Windows/ui-catch.i}
END METHOD.
|
...
SCL-3012 Workflow overview / task list
Description:
We have implemented the new form Consultingwerk.Windows.Framework.Workflow.WorkflowInstanceForm to support displaying active workflow instances (for the current user).
Application services that intend to provide workflow instances (task items) need to subscribe to the event CollectWorkflowInstances of the Consultingwerk.SmartFramework.Workflow.IWorkflowEngine service.
| Code Block | ||
|---|---|---|
| ||
/**
* Purpose: Event raised to collect ttWorkflowStatus records of various provides
* Notes:
* @param dsWorkflowStatus INPUT-OUTPUT Dataset with workflow status records
*/
DEFINE EVENT CollectWorkflowInstances SIGNATURE VOID (INPUT-OUTPUT DATASET dsWorkflowStatus) .
|
When the event is raised multiple subscribers are called and can add records to the ttWorkflowStatus temp-table in the dsWorkflowStatus dataset.
A sample implementation of such a subscriber can be a service subscribing to the events of the IWorkflowEngine when started
| Code Block | ||
|---|---|---|
| ||
/**
* Purpose: Initializer/Startup
* Notes:
*/
METHOD PUBLIC VOID initialize ():
DEFINE VARIABLE oWorkflowEngine AS IWorkflowEngine NO-UNDO .
oWorkflowEngine = {Consultingwerk/get-service.i IWorkflowEngine
"NEW WorkflowEngine ()"} .
oWorkflowEngine:CollectWorkflowInstances:Subscribe (CollectWorkflowInstancesHandler) .
oWorkflowEngine:OpenWorkflowInstance:Subscribe (OpenWorkflowInstanceHandler) .
END METHOD .
|
and an event handler for the CollectWorkflowInstances event:
| Code Block | ||
|---|---|---|
| ||
/**
* Purpose: Event handler for the CollectWorkflowInstances event of the Workflow engine
* Notes:
* @param dsWorkflowStatus INPUT-OUTPUT Dataset with workflow status records
*/
METHOD PROTECTED VOID CollectWorkflowInstancesHandler (INPUT-OUTPUT DATASET dsWorkflowStatus):
DEFINE VARIABLE oEntity AS OrderBusinessEntity NO-UNDO .
oEntity = CAST (ServiceManager:GetBusinessService (SmartComponentsDemoServices:OERA:Sports2000:OrderBusinessEntity,
BusinessServiceOperatingModeEnum:UnmanagedWhenInCallStack),
OrderBusinessEntity) .
oEntity:GetWorkflowInstances (INPUT-OUTPUT DATASET dsWorkflowStatus BY-REFERENCE) .
END METHOD.
|
This subscriber may call into a method of a Business Entity (a Business Entity is typically not suited to subscribe to the event directly, as Business Services may not always be running).
In the method of the Business Entity, ttWorkflowStatus records are typically created using the CreateWorkflowStatusRecord API of the IWorkflowEngine service. The application logic needs to assign the Assignee,WorkflowTimestamp and RecordDescription fields accordingly.
| Code Block | ||
|---|---|---|
| ||
/**
* Purpose: Adds the OrderApproval workflow items to the dsWorkflowStatus
* Notes:
* @param dsWorkflowStatus INPUT-OUTPUT Dataset with workflow status records
*/
METHOD PUBLIC VOID GetWorkflowInstances (INPUT-OUTPUT DATASET dsWorkflowStatus):
DEFINE VARIABLE oWorkflowEngine AS IWorkflowEngine NO-UNDO .
DEFINE VARIABLE oRequest AS FetchDataRequest NO-UNDO .
DEFINE VARIABLE oSalesrep AS SalesRepDatasetModel NO-UNDO .
DEFINE VARIABLE cCustName AS CHARACTER NO-UNDO .
oWorkflowEngine = {Consultingwerk/get-mandatory-service.i IWorkflowEngine} .
oSalesrep = NEW SalesRepDatasetModel() .
oSalesrep:Salesrep:Filter:SalesRep:EQ("HXM":U):Run().
oRequest = NEW FetchDataRequest ("eOrder,eCustomer":U,
"for each eOrder where (eOrder.OrderStatus = 'Ordered'~
or eOrder.OrderStatus = 'Approval pending'~
or eOrder.OrderStatus = 'Approved'~
or eOrder.OrderStatus = 'Partially Shipped') and eOrder.Salesrep = 'HXM' by eOrder.OrderDate descending":U,
500) .
THIS-OBJECT:FetchData(oRequest).
FOR EACH eOrder:
oWorkflowEngine:CreateWorkflowStatusRecord (BUFFER ttWorkflowStatus:HANDLE,
THIS-OBJECT:GetClass():TypeName,
BUFFER eOrder:HANDLE,
"OrderApproval":U) .
IF CAN-FIND (eCustomer WHERE eCustomer.CustNum = eOrder.CustNum) THEN DO:
{&_proparse_ prolint-nowarn(findnoerror)}
FIND eCustomer WHERE eCustomer.CustNum = eOrder.CustNum .
ASSIGN cCustName = eCustomer.Name.
END.
ELSE
ASSIGN cCustName = "<Customer not available>":U .
ASSIGN ttWorkflowStatus.Assignee = oSalesrep:Salesrep:RepName
ttWorkflowStatus.WorkflowTimestamp = DATETIME-TZ (eOrder.OrderDate, (eOrder.Ordernum MODULO 86400) * 1000).
CASE eOrder.OrderStatus:
WHEN "Ordered":U THEN
ASSIGN ttWorkflowStatus.RecordDescription = SUBSTITUTE ("Approval pending for Order &1, Promise Date &2, &3":U,
eOrder.Ordernum, eOrder.PromiseDate, cCustName) .
WHEN "Approval pending":U THEN
ASSIGN ttWorkflowStatus.RecordDescription = SUBSTITUTE ("Awaiting approval for Order &1, Promise Date &2, &3":U,
eOrder.Ordernum, eOrder.PromiseDate, cCustName) .
WHEN "Approved":U THEN
ASSIGN ttWorkflowStatus.RecordDescription = SUBSTITUTE ("Awaiting shipping for Order &1, Promise Date &2, &3":U,
eOrder.Ordernum, eOrder.PromiseDate, cCustName) .
WHEN "Partially Shipped":U THEN
ASSIGN ttWorkflowStatus.RecordDescription = SUBSTITUTE ("Complete shipping for Order &1, Promise Date &2, &3":U,
eOrder.Ordernum, eOrder.PromiseDate, cCustName) .
END CASE .
RELEASE ttWorkflowStatus .
END.
END METHOD.
|
...
SCL-3032 Implemented fix method for corrupted dock manager settings
Description:
Some customers have experienced every now and then corrupted Infragistics Dock Manager settings being stored and restored when GUI for .NET applications have been launched. Some customers more frequently than others. Some customers never. A typical result of broken Dock Manager settings has been that the Infragistics Column Chooser has not been rendered in a Dockable Pane and those just overlaid some random location on the main window.
We have found various sources in the Infragistics Forum (e.g. https://www.infragistics.com/community/forums/f/ultimate-ui-for-windows-forms/120296/ultradockmanager---loading-invalid-dock-layout-crashes-application ) and other sites indicating that this might be an issue in the Infragistics component when saving the settings.
We have now added code to our reference MainMenuForm which detects this situation and will automatically reset the stored Dock Manager settings to avoid the disturbance for the users.
The following code has been added in the OnLoad() method around the call to the DockManagerHelper:RestoreFromSettingsService ().
| Code Block | ||
|---|---|---|
| ||
/* Prepare restoring of initial Dock Manager settings in case restoring the stored settings fails. */
oDockedControls = DockManagerHelper:GetDockedControls(ultraDockManager1) .
DO ON ERROR UNDO, THROW:
oMemoryStream = NEW MemoryStream() .
ultraDockManager1:SaveAsXML(oMemoryStream) .
/* DockManager */
DockManagerHelper:RestoreFromSettingsService (ultraDockManager1,
THIS-OBJECT:WindowPositionRegistryKey) .
IF NOT DockManagerHelper:EnsureDockedControls(ultraDockManager1, oDockedControls) THEN DO:
oMemoryStream:Seek(0, SeekOrigin:Begin) .
ultraDockManager1:LoadFromXML(oMemoryStream) .
END.
FINALLY:
IF VALID-OBJECT (oMemoryStream) THEN
oMemoryStream:Dispose() .
IF VALID-OBJECT (oMemoryStream) THEN
DELETE OBJECT oMemoryStream .
END FINALLY.
END.
|
...